src/Main/BUILD.gn

# Copyright 2016 The SwiftShader Authors. All Rights Reserved.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#    http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

# Need a separate config to ensure the warnings are added to the end.
config("swiftshader_main_private_config") {
  if (is_clang) {
    cflags = [
      "-DLOG_TAG=\"swiftshader_main\"",
      "-msse2",
    ]

    if (!is_debug) {
      cflags += [
        "-DNDEBUG",
        "-DANGLE_DISABLE_TRACE",
      ]
    }
  }
}

source_set("swiftshader_main") {
  deps = [
    "../Common:swiftshader_common",
  ]

  sources = [
    "Config.cpp",
    "FrameBuffer.cpp",
    "SwiftConfig.cpp",
  ]

  if (host_os == "linux") {
    sources += [
      "libX11.cpp",
      "FrameBufferX11.cpp",
    ]
  } else if (host_os == "mac") {
    sources += [
      "FrameBufferOSX.mm",
    ]
  } else if (host_os == "win") {
    sources += [
      "FrameBufferDD.cpp",
      "FrameBufferGDI.cpp",
      "FrameBufferWin.cpp",
    ]
  }

  configs += [
    ":swiftshader_main_private_config",
  ]

  include_dirs = [
    "..",
    "../Common",
  ]
}